Результат моделирования (Рисунок 10) показывает, что данная схема работает как потенциометр, управляемый напряжением. Напряжение на движке потенциометра меняется в диапазоне (0…10) В при изменении входного управляющего напряжения в диапазоне (0…1) В.
 |
|
| Рисунок 10. | Результат моделирования поведенческой модели управляемого напряжением потенциометра (Рисунок 9). |
Схема (Рисунок 9) нарисована таким образом, что было удобно сделать экстракцию PSpice макромодели потенциометра. Если из схемы удалить все цепи с источниками V1, V2, V3, V4 и сгенерировать NET-листинг (Листинг 2), то получим почти готовую макромодель. (После удаления лишних для экстракции цепей входы схемы потенциометра станут висящими, и транслятор в NET-листинг PSpice выдаст сообщение об ошибке, однако трансляцию NET-листинга надо продолжить, она все равно состоится). Ее надо оформить по правилам PSpice, немного доработать и создать условное графическое изображение, чтобы использовать в схемных проектах.
Листинг 2
* source ORCAD_166
G_ABM2I1 1 3 VALUE { {V(1,3)/(1-LIMIT( V(4,5), 0.999999, 0))/RES} }
G_ABM2I2 3 2 VALUE { {V(3,2)/LIMIT( V(4,5), 1, 1e-6)/RES} }
R_R2 2 3 1T TC=0,0
R_R1 3 1 1T TC=0,0
.PARAM res=10
C использованием полученных на предыдущих этапах результатов созданы две макромодели управляемых напряжением потенциометров VC_POT и VC_POTV.
УГО потенциометра VC_POT показано на Рисунке 11, PSpice макромодель представлена в Листинге 3. Управляется этот потенциометр разностью входных напряжений, изменяющейся в диапазоне (0…1) В, что соответствует доле, на которую сдвинулся движок потенциометра от вывода, обозначенного «0» на УГО. Источник управляющего напряжения может быть плавающим.
 |
|
| Рисунок 11. | Управляемый напряжением резистор VC_POT. |
УГО потенциометра VC_POTV показано на Рисунке 12, PSpice макромодель представлена в Листинге 4. Управляется этот потенциометр напряжением, изменяющемся в диапазоне от (0…1) В, что соответствует доле, на которую сдвинулся движок потенциометра от вывода, обозначенного «0» на УГО. Отличие от потенциометра VC_POTV от VC_POT заключается в том, что управляющее напряжение отсчитывается всегда от нулевого потенциала. Для большинства задач потенциометра VC_POTV достаточно, а его УГО более удобно в использовании.
 |
|
| Рисунок 12. | Управляемый напряжением резистор VC_POTV. |
Листинг 3
*$
* Device type: Voltage Controlled Potentiometer
* Device name: VC_POT
* Aythor: [email protected] Petrakov Oleg
* Date: 16 Dec 2015
.SUBCKT VC_POT 1 2 3 4 5 PARAMS: RES=1K
G1 1 3 VALUE={V(1,3)/(1-LIMIT( V(4,5), 0.999999, 0))/RES}
G2 3 2 VALUE={V(3,2)/LIMIT( V(4,5), 1, 1e-6)/RES}
R1 1 3 1T
R2 2 3 1T
.ENDS
*$
Листинг 4
*$
* Device type: Voltage Controlled Potentiometer
* Device name: VC_POTV
* Aythor: [email protected] Petrakov Oleg
* Date: 16 Dec 2015
.SUBCKT VC_POTV 1 2 3 4 PARAMS: RES=1K
G1 1 3 VALUE={V(1,3)/(1-LIMIT( V(4), 0.999999, 0))/RES}
G2 3 2 VALUE={V(3,2)/LIMIT( V(4), 1, 1e-6)/RES}
R1 1 3 1T
R2 2 3 1T
.ENDS
*$
Созданным моделям можно доверять, если они проверены. Для этого можно придумать специальные схемы тестирования (это более эффективно), либо использовать модель в конкретных проектах, где она должна проявить свою адекватность.
 |
|
| Рисунок 13. | Схема тестирования потенциометра VC_POT. |
На Рисунке 13 показана схема тестирования управляемого напряжением потенциометра VC_POT, а на Рисунке 14 – результат моделирования этой схемы в режиме TRANSIENT. При этом в качестве управляющего напряжения используется плавающий источник линейно-нарастающего напряжения V2, который находится под потенциалом источника V3. По результатам моделирования видно, что при изменении дифференциального напряжения на управляющих входах потенциометра VC_POT в диапазоне (0 … 1) В, напряжение на движке потенциометра VC_POT меняется в диапазоне (0 … 10) В. Ток через потенциометр сопротивлением 1К равен 10 мА. Все это позволяет говорить, что PSpice модель потенциометра VC_POT работает правильно.
 |
|
| Рисунок 14. | Результат TANSIENT моделирования схемы (Рисунок 13). |
 |
|
| Рисунок 15. | Схема тестирования потенциометра VC_POTV. |
На Рисунке 15 изображена схема тестирования управляемого напряжением потенциометра VC_POTV с использованием описанной ранее модели Ohmmeter. На Рисунке 16 показан результат моделирования этой схемы в режиме TRANSIENT. При этом в качестве управляющего напряжения используется источник линейно-нарастающего напряжения V2, включенный относительно земли. По результатам моделирования (Рисунок 16) видно, что при изменении напряжения на управляющем входе потенциометра VC_POTV в диапазоне (0 … 1) В напряжение на движке потенциометра VC_POTV меняется в диапазоне (0 … 10) В. Омметр U2 показывает, что сопротивление движка потенциометра относительно земли меняется от 0 до 15 Ом. Это позволяет утверждать, что модель управляемого напряжением потенциометра VC_POTV работает правильно.
 |
|
| Рисунок 16. | Результат TANSIENT моделирования схемы (Рисунок 15). |
Пример применения управляемого напряжением потенциометра VC_POTV в реальном проекте регулятора мощности на микросхеме КР1182ПМ1 показан на Рисунке 17. При моделировании в среде OrCAD выводы «NC» компонента КР1182ПМ1 необходимо отметить как неподключенные. Влияние температуры в макромодели КР1182ПМ1 (Листинг 5) не учитывается. Автор модели микросхемы КР1182ПМ1 – Семенов Ю. В.
 |
|
| Рисунок 17. | Регулятор мощности на микросхеме КР1182ПМ1 |
Отечественная микросхема КР1182ПМ1 представляет собой интегральный тиристорный регулятор мощности, способный работать при напряжении сети переменного тока 220 В. При этом микросхема обеспечивает следующие функции: защиту ламп накаливания от перегорания при включении, регулировку яркости свечения ламп, плавное включение и выключение ламп, регулировку мощности до 150 Вт без использования дополнительных тиристоров или параллельного включения двух микросхем, возможность последовательного включения с нагрузкой, ограничение выдаваемой в нагрузку мощности при достижении микросхемой предельно допустимой мощности рассеивания, использование маломощных и низковольтных внешних элементов управления. Более подробно о применении этой микросхемы написано в журнале «Ремонт и сервис» №6 за июнь 2002 г.
Листинг 5
.SUBCKT KR1182PM1 AC11 AC12 AC21 AC22 C+ C- UST1+ UST2+
* | | | | | | | |
* силовые выводы 1 | | | | | |
* силовые выводы 2 | | | |
* управление+ | | |
* управление- | |
* управляющий электрод 1 |
* управляющий электрод 2
* PSpice модель KR1182PM1 предназначена для моделирования
* микросхемы КР1182ПМ1. Влияние температуры не учитывается.
* Сопровождается компонентом и корпусом для системы Orcad.
* При моделировании в среде Orcad выводы "NC" компонента
* необходимо отметить как неподключенные.
* Модель создана 29.04.02 на основе оригинальной
* схемотехники разработчика и производителя микросхемы
* КР1182ПМ1 - ЗАО НТЦ СИТ http: www.bryansk.ru/sit
* Автор Семенов Ю. В. (8632) 36-90-57, E-mail: [email protected]
XVS2 AC11 UST2+ AC21 VS
* C B E
Q5 N6 N7 N9 NOUT
R6 N10 C- 10k
D5 C- AC21 VD
Q4 N6 N6 N5 POUT
R7 N13 C- 3.6k
R3 N5 N7 1000k
D4 N3 AC11 VD
Q3 N7 N6 N5 POUT
Q2 AC21 N4 UST2+ POUT
R1 N2 N5 10k
D1 N1 N2 VD
D8 C- N7 DZ1
R4 N9 N15 60k
D3 N8 UST2+ VD
R2 N3 C- 10k
Q1 AC11 N1 UST1+ POUT
Q8 N12 N12 N9 POUT
Q10 N11 N10 N9 POUT
R5 N15 C- 4.35k
D2 N4 N5 VD
X1 AC21 UST1+ AC11 VS
D6 N8 UST1+ VD
Q9 N8 N12 N9 POUT
Q12 C+ N15 C- NOUT
Q13 C- C+ N11 POUT
Q7 N14 N10 N9 POUT
D7 N14 C+ VD
Q11 N12 N11 N13 NOUT
Q6 N10 N10 N9 POUT
.ENDS
*$
.SUBCKT VS 1 2 3
* C B E
QP 2 4 1 POUT OFF
QN 4 2 3 NOUT OFF
RF 2 4 800MEG
RR 1 4 533MEG
RGK 2 3 20000
DF 2 4 ZF
DR 1 4 ZR
DGK 2 3 ZGK
.MODEL ZF D (IS=3.2E-16 IBV=100N BV=400)
.MODEL ZR D (IS=3.2E-16 IBV=100N BV=400)
.MODEL ZGK D (IS=3.2E-16 IBV=100N BV=5)
.ENDS
*$
.MODEL POUT PNP (IS=320F BF=1 CJE=134P TF=8.06U)
.MODEL NOUT NPN (IS=320F BF=100 RC=0.6 CJE=670P CJC=134P TF=538N)
.MODEL VD D(Is=0.1p Rs=16 CJO=2p Tt=12n Bv=500 Ibv=0.1p)
.MODEL DZ1 D( BV=7 IBV=0.01
*$
Для подключения библиотек к OrCAD v16.6 при его стандартной инсталляции необходимо выполнить следующие действия.
- Разархивировать файл с приложениями к статье в любое место на диске компьютера.
- Скопировать папку PSPICE166_Articles с библиотеками в каталог c:Cadence.
- Скопировать текстовый файл nom_user_Articles.lib в папку CadenceSPB_16.6 oolspspicelibrary. В этом файле должен содержаться следующий текст, с указанием путей к библиотечным файлам:
* Library of user Oleg Petrakov devices: Analog and Digital
*
* -------------------- ARTIKLES_Potentiometer ---------------------
.lib c:CadencePSPICE166_ArticlesPotentiometerVC_POT.lib
.lib c:CadencePSPICE166_ArticlesPotentiometerVC_POTV.lib
.lib c:CadencePSPICE166_ArticlesPotentiometerOhmmeter.lib
.lib c:CadencePSPICE166_ArticlesPotentiometerKR1182PM1.lib
* end of library file
4. Отредактировать текстовый файл c:CadenceSPB_16.6 oolspspicelibrary om.lib. В конец файла следует записать следующие строки, чтобы подключить пользовательскую библиотеку nom_user_Articles.lib и сохранить измененный файл:
* User Oleg Petrakov
.lib "nom_user_Articles.lib"
* end of library file
Запустить проект OrCAD, содержащий новые библиотечные компоненты, и убедиться, что PSpice моделирование происходит. На этом все!
 |
|
| Рисунок 18. | Результат моделирования схемы (Рисунок 17) в режиме TRANSIENT. Средний график – напряжение сети. Нижний график – напряжение на нагрузке R2. Управляемый линейно-нарастающим напряжением от 0 В до 1 В (верхний график) потенциометр R1 меняет свое сопротивление от 0 до 20К. При этом видно в динамике, как меняется угол отсечки напряжения на нагрузке в зависимости от положения движка потенциометра. |
Примечание
Эти библиотеки можно подключить и к более старым версиям OrCAD, например к популярной еще версии OrCAD v9.1. Библиотечные файлы с расширением *.LIB следует оставить без изменений, а вот файлы с расширением *.OLB, содержащие УГО компонентов, придется создать заново с помощью редактора OrCAD Capture v9.1. Все остальные действия по подключению библиотек к OrCAD аналогичны описанным выше.
Литература
- Разевиг В. Д. Система проектирования OrCAD 9.2. СОЛОН. Москва 2001 г.
- Архангельский А. Я. PSpice и Design Center. Ч. 1. Схемотехническое моделирование. Модели элементов. Макромоделирование. М.: МИФИ, 1996 г.
- Петраков О. М. Создание аналоговых PSPICE-моделей радиоэлементов.— М.: ИП РадиоСофт, 2004.— 208 с.: ил.— (Книжная полка радиолюбителя. Вып. 8)
- Хайнеман Р. Визуальное моделирование электронных схем в PSPICE. Пер. с нем. – М.: ДМК Пресс, 2008. 336 с.: ил.
- Кеоун Дж. OrCAD Pspice. Анализ электрических цепей (+DVD). — М.: ДМК Пресс СПб.: Питер, 2008. — 640 с.: ил.
- Петраков О. М. Поведенческое моделирование в PSPICE. Журнал Схемотехника №3, №4 за 2003 г.
