В статье предлагаются идеализированные частотно независимые и однополюсные частотно-зависимые Pspice макромодели трансимпедансного операционного усилителя. Частотно независимые модели позволяют более эффективно моделировать некоторые проекты, для которых важна возможность точно оценить влияние внешней обвязки трансимпедансного операционного усилителя на характеристики проектируемого устройства. Однополюсные частотно-зависимые модели достаточно точно описывают частотные и усилительные свойства большинства операционных усилителей этого типа. Это позволяет оценить верхнюю границу трансимпеданса на постоянном токе и частоту единичного трансимпеданса операционного усилителя, который следует использовать в проектируемом усилительном или фильтрующем устройстве.
Введение
Основным преимуществом операционных усилителей (ОУ) с токовой обратной связью (Трансимпедансных операционных усилителей) является широкая рабочая полоса частот. Обычно усилители с ОС по току строятся на базе биполярных транзисторов, т.к. типовая сфера их применения - высокоскоростные коммуникации, видео и т.д., как правило, не требует высоких входных импедансов и размаха выходных напряжений равного питающему напряжению (rail to rail). Типовым рабочим диапазоном для трансимпедансного ОУ является область от примерно 25 МГц до нескольких ГГц. Это достигается за счёт специфической схемной конфигурации трансимпедансного ОУ, при использовании одинаковых технологических процессов.
Универсальный ключ к успеху в разработке хороших схем на ОУ – это понимание того, как работает схема и составляющие её компоненты. Этому способствуют идеализированные модели ОУ, которые описываются простейшими соотношениями, в то время как сложная модель реального ОУ, без надлежащего её изучения, будет для пользователя чёрным ящиком. Поэтому идеализированные модели ОУ очень востребованы для моделирования. Причина этого в том, что большинство теоретических выкладок относительно свойств схем с применением ОУ, сделаны в предположении идеальности ОУ. Поэтому идеальные модели незаменимы, когда требуется обкатать идею или свериться с теорией применения ОУ. В дальнейшем можно выбрать для этой же схемы более сложную PSpice модель реально производимого ОУ, но работать схема уже будет с учётом множества параметров неидеальности выбранного ОУ. После это, в некоторых случая, потребуется скорректировать номиналы радиоэлементов, чтобы вернуть схеме расчётные параметры.
В OrCAD v16.6 [1, 2, 3, 4] есть модель идеализированного операционного усилителя OPAMP (Рисунок 1). Она находится в библиотеке analog.olb. Усиление ОУ по умолчанию GAIN=1MEG. Напряжения питания ОУ по умолчанию VPOS=+15V, VNEG=-15V. По умолчанию параметры модели OPAMP скрыты от показа. Однако их можно сделать видимыми на схеме, если войти в меню Edit/Properties (Редактирование свойств) и при помощи кнопки Display сделать видимыми Name and Value (Имя и значение параметров). Работа модели OPAMP описывается шаблоном PSpice Template (Рисунок 1), в котором записано математическое выражение на языке PSpice, использующее функцию LIMIT. Функция LIMIT требуется, чтобы ограничить выходное напряжение этой модели ОУ в диапазоне напряжений питания реального ОУ (VNEG, VPOS). Стандартное питание ОУ ±15 В.
 |
||
| PSpice Template = E^@REFDES %OUT 0 VALUE {LIMIT(V(%+,%-)*@GAIN,@VNEG,@VPOS)} | ||
| Рисунок 1. | УГО идеализированного стандартного ОУ из библиотеки analog.olb и его PSpice Template (шаблон). |
|
Однако, в OrCAD v16.6 (как и более древних версиях) нет идеализированных моделей трансимпедансных ОУ [5, 6] со свойствами, аналогичными модели OPAMP. Это ограничивает возможность моделирования некоторых схем в OrCAD, для которых важна возможность точно оценить влияние внешней обвязки трансимпедансных ОУ на характеристики проектируемого устройства.
В статье предлагаются шесть идеализированных макромоделей трансимпедансных ОУ, различающихся по уровню сложности (T1, T2, T3).
OPAMP_T1 - самая простая, моделируется частотно не зависимый трансимпеданс
OPAMP_T1_F1 – самая простая, моделируется частотно-зависимый трансимпеданс
OPAMP_T2 - моделирует частотно не зависимый трансимпеданс и входное сопротивление
OPAMP_T2_F1- моделирует частотно-зависимый трансимпеданс и входное сопротивление
OPAMP_T3 - моделирует частотно не зависимый трансимпеданс и входное и выходное сопротивление
OPAMP_T3_F1- моделирует частотно-зависимый трансимпеданс и входное и выходное сопротивление
УГО частотно-зависимой (самой сложной) макромодели трансимпедансного ОУ, получившей имя OPAMP_T2_F1, показана на Рисунке 2. УГО остальных моделей отличается только количеством поддерживаемых параметров. Как видим, УГО трансимпедансных ОУ ничем не отличаются от модели обычного ОУ с именем OPAMP, кроме наличия дополнительных параметров.
Таким образом, задача сводится к тому, чтобы создать модели трансимпедансных ОУ с подобными модели OPAMP характеристиками по постоянному току.
 |
||
| Рисунок 2. | УГО идеализированной частотно-зависимой макромодели OPAMT_T3_F1 трансимпедансного ОУ |
|
Математическая модель трансимпедансного ОУ с одним частотным полюсом
На Рисунке 3 приведена относительно подробная линеаризированная схема частотно-зависимой однополюсной макромодели ОУ с ОС по току (Трансимпедансного ОУ). Неинвертирующий вход этого ОУ является входом встроенного буфера E1 и имеет очень высокий импеданс, подобный импедансу в ОУ на биполярных транзисторах с ОС по напряжению. Инвертирующий вход ОУ соединён с выходом буфера E1 так, что входной импеданс инвертирующего входа оказывается очень мал. Этот импеданс указан в модели как Rn и обычно составляет менее 50 Ом. Коэффициент передачи входного буфера E1 принимаем равным 1, что очень близко к реальному значению.
Выходной буфер E2 обеспечивает низкий выходной импеданс усилителя Rout, его коэффициент передачи также считается равным 1. Эти параметры начинают оказывать влияние на поведение схемы при малом сопротивлении нагрузки или её ёмкостном характере, но это пока не рассматривается. Впрочем, с точки зрения обеспечения стабильности схемы на высоких частотах выходным импедансом ОУ уже нельзя пренебрегать (в общем случае это комплексная величина).
F1 — источник напряжения, управляемый током (трансимпедансный усилитель). Трансимпеданс в ОУ с ОС по току выполняет ту же функцию, что и коэффициент усиления в ОУ с ОС по напряжению. Обычно трансимпеданс очень высок, порядка мегаом, так что коэффициент передачи в ОУ с замкнутой ОС по току и прочие параметры схемы зависят только от параметров пассивных элементов в цепи ОС, так же как и в ОУ с ОС по напряжению.
Пользуясь этой общей моделью, мы построим несколько разновидностей PSpice макромоделей трансимпедансных ОУ разных по сложности.
В общем случае трансимпеданс Zt = f(Rt,Ct) - комплексная величина. Наша задача заключается в том, чтобы найти формулу для вычисления ёмкости конденсатора Сt, выраженную через частоту единичного усиления F1 и трансимпеданс на постоянном токе Rt.
Для этого воспользуемся системой компьютерной математики Maple (Листинг 1).
 |
||
| Рисунок 3. | Схема линеаризированной частотно-зависимой однополюсной макромодели трансимпедансного ОУ (OPAMP_T3_F1). |
|
Листинг 1
Составим систему уравнений Кирхгофа для схемы (Рисунок 3).
> restart:
> print(`Уравнения Кирхгофа`);
eq1:=(V4-VOUT)/Rout=0;
eq2:=-I1+(V1-VINN)/Rn=0;
eq3:=(V1-V2)/Rn-I1=0;
eq4:=-(V1-VINN)/Rn-V3/Rt-V3*s*Ct=0;
eq5:=V1=0;
eq6:=V4 = V3;
Уравнения Кирхгофа
Решим эту систему уравнений относительно V1, V2, V3, V4, VINN, VOUT и найдём трансимпеданс ОУ с разомкнутой ОС в операторном виде.
> solve({eq1,eq2,eq3,eq4,eq5,eq6},{V1,V2,V3,V4,VINN,VOUT}):
assign(%); Zt:=VOUT/I1;
Переведём трансимпеданс в частотную область
> Zt:=subs(s=I*2*Pi*f,Zt);
Составим и решим уравнение, из которого найдём частоту F1, на которой модуль трансимпеданса в частотной области равен единице.
> F1=solve(evalc(abs(Zt))=1,f)[3];
Считая Rt заданным, выразим Ct через частоту единичного трансимпеданса F1
> Ct:=solve(%,Ct);
Запишем это выражение в формате Pspice для последующего использования в PSpice макромоделях.
C:= { SQRT(Rt^2-1)/(2*Pi*F1*Rt) } (1)
Создание макромоделей трансимпедансных ОУ
Для начала построим самые простые (предельно идеализированные) модели трансимпедансных ОУ - OPAMP_T1 (частотно не зависимая) и OPAMP_T1_F1 (частотно-зависимая). Они предназначены в основном для исследования влияния внешней обвязки и частотного полюса ОУ на характеристики усилительных и фильтрующих схем в идеальных условиях.
Построим поведенческие модели OPAMP_T1 частотно не зависимой (Рисунок 4) и OPAMP_T1_F1 частотно-зависимой макромодели трансимпедансного ОУ. Для этого будем использовать блоки поведенческого моделирования из библиотеки ANALOG.olb и AMB.olb [3, 6]. Поведенческий блок AVM1, по аналогии с моделью OPAMP (Рисунок 1), на языке Pspice описываются выражением LIMIT( V(%IN) , VNEG, VPOS).
 |
||
| Рисунок 4. | Поведенческая модель OPAMP_T1 частотно независимого трансимпедансного ОУ |
|
 |
||
| Рисунок 5. | Поведенческая модель OPAMP_T1_F1 частотно-зависимого трансимпедансного ОУ |
|
Схемы нарисованы таким образом, что было удобно сделать экстракцию PSpice макромоделей. Для экстракции заготовки макромодели требуется сгенерировать NET-листинг в OrCAD Capture (Даже если транслятор в Pspice NET-листинг выдаст сообщение об ошибке надо продолжить трансляцию NET-листинга, она все равно состоится). Получим заготовки макромоделей для OPAMP_T1 (Листинг 2) и для OPAMP_T1_F1 (Листинг 3) Эти заготовки надо оформить как макромодели по правилам Spice и создать условные графические изображения, чтобы использовать их в схемных проектах.
Готовые PSpice макромодели OPAMP_T1 и OPAMP_T1_F1 представлены в Листинге 4. Глядя на текст макромоделей (Листинг 4) видим, что за трансимпеданс на постоянном токе отвечает резистор Rt, а за частоту единичного усиления F1 отвечает модель конденсатора с именем CF1. Параметр С модели CF1 записан формулой, в соответствии с (1). При запуске моделирования PSpice вычислит требуемую ёмкость по этой формуле, исходя из заданных параметров GAIN и F1, и подставит её как номинал С1.
Листинг 2
* source ORCAD_166
E_E1 1 0 INP 0 1
E_ABM1 OUT 0 VALUE { LIMIT(V(2),VNEG,VPOS) }
X_F1 1 INN 2 0 SCHEMATIC1_F1
R_Rt 0 2 {RT} TC=0,0
PARAM rt=10meg vneg=-15 vpos=15
.subckt SCHEMATIC1_F1 1 2 3 4
F_F1 3 4 VF_F1 1
VF_F1 1 2 0V
.ends SCHEMATIC1_F1
Листинг 3
* source ORCAD_166
E_E1 1 0 INP 0 1
C_Ct 0 2 {CF1} TC=0,0
E_ABM1 OUT 0 VALUE {LIMIT(V(2),VNEG,VPOS)}
X_F1 1 INN 2 0 SCHEMATIC1_F1
R_Rt 0 2 {RT} TC=0,0
.PARAM rt=10meg vneg=-15 cf1=1p vpos=15
.subckt SCHEMATIC1_F1 1 2 3 4
F_F1 3 4 VF_F1 1
VF_F1 1 2 0V
.ends SCHEMATIC1_F1
Листинг 4
* PSpice Model Editor - Version 16.6
*
* Library of new analog primitives
* Date: 25 August 2016
*$
* Device name: OPAMP_T1
* Device type: Transimpedance OpAmp (DC model)
*
* Rt - DC Transimpedanc
*
.SUBCKT OPAMP_T1 INP INN OUT
+ PARAMS: RT=10MEG VPOS=15 VNEG=-15
VF1 1 INN 0V
F1 2 0 VF1 1
E1 1 0 INP 0 1
Rt 0 2 {RT}
EABM1 OUT 0 VALUE {LIMIT(V(2),VNEG,VPOS)}
.ENDS OPAMP_T1
*$
* Device name: OPAMP_T1_F1
* Device type: Transimpedance OpAmp (Fequency-dependent)
*
* Rt - DC Transimpedanc
* F1 - Freguence single Transimpedanc
*
.SUBCKT OPAMP_T1_F1 INP INN OUT
+ PARAMS: RT=10MEG F1=1E9 VPOS=15 VNEG=-15
VF1 1 INN 0V
F1 2 0 VF1 1
E1 1 0 INP 0 1
Ct 0 2 CF1 1
Rt 0 2 {RT}
EABM1 OUT 0 VALUE {LIMIT(V(2),VNEG,VPOS)}
.model CF1 CAP C={SQRT(RT^2-1)/(2*F1*RT*Pi)}
.ENDS OPAMP_T1_F1
*$
Аналогично построим модели трансимпедансных ОУ - OPAMP_T2 (частотно независимая) и OPAMP_T2_F1 (частотно-зависимая). Они отличаются наличием резистора Rn (выходное сопротивление входного буфера). Они также предназначены в основном для исследования влияния внешней обвязки и частотного полюса ОУ на характеристики усилительных и фильтрующих схем.
Схема для экстракции PSpice макромодели частотно независимой однополюсной макромодели OPAMP_T2 трансимпедансного ОУ показана на Рисунке 6. Результат экстракции представлен в Листинге 5. Готовая PSpice макромодель этого ОУ для OrCAD v16.6 представлена в Листинге 7..
Схема для экстракции PSpice макромодели частотно-зависимой однополюсной макромодели OPAMP_T2_F1 трансимпедансного ОУ показана на Рисунке 7. Результат экстракции представлен в Листинге 6. Готовая PSpice макромодель этого ОУ для OrCAD v16.6 представлена в Листинге 7.
 |
||
| Рисунок 6. | Поведенческая модель OPAMP_T2 частотно-зависимого трансимпедансного ОУ |
|
 |
||
| Рисунок 5. | Поведенческая модель OPAMP_T2_F1 частотно-зависимого трансимпедансного ОУ. |
|
Листинг 5
* source ORCAD_166
E_E1 1 0 INP 0 1
E_ABM1 OUT 0 VALUE { LIMIT(V(3),VNEG,VPOS) }
R_Rn 2 1 {Rn} TC=0,0
X_F1 2 INN 3 0 SCHEMATIC1_F1
R_Rt 0 3 {RT} TC=0,0
.PARAM rt=10meg vneg=-15 rn=25 vpos=15
.subckt SCHEMATIC1_F1 1 2 3 4
F_F1 3 4 VF_F1 1
VF_F1 1 2 0V
.ends SCHEMATIC1_F1
Листинг 6
* source ORCAD_166
E_E1 1 0 INP 0 1
C_Ct 0 3 {CF1} TC=0,0
E_ABM1 OUT 0 VALUE { LIMIT(V(3),VNEG,VPOS) }
R_Rn 2 1 {Rn} TC=0,0
X_F1 2 INN 3 0 SCHEMATIC1_F1
R_Rt 0 3 {RT} TC=0,0
.PARAM rt=10meg vneg=-15 cf1=1p rn=25 vpos=15
.subckt SCHEMATIC1_F1 1 2 3 4
F_F1 3 4 VF_F1 1
VF_F1 1 2 0V
.ends SCHEMATIC1_F1
Листинг 7
*$
* Device name: OPAMP_T2
* Device type: Transimpedance OpAmp (DC model)
*
* Rt - DC Transimpedanc
* Rn - Input resistance
*
.SUBCKT OPAMP_T2 INP INN OUT
+ PARAMS: RT=10MEG RN=25 VNEG=-15 VPOS=15
VF1 2 INN 0V
F1 3 0 VF1 1
E1 1 0 INP 0 1
Rn 2 1 {Rn}
Rt 0 3 {RT}
EABM1 OUT 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
.ENDS OPAMP_T2
*$
* Device name: OPAMP_T2_F1
* Device type: Transimpedance OpAmp (Fequency-dependent)
*
* Rt - DC Transimpedanc
* F1 - Freguence single Transimpedanc
* Rn - Input resistance
*
.SUBCKT OPAMP_T2_F1 INP INN OUT
+ PARAMS: RT=10MEG F1=1E9 RN=25 VNEG=-15 VPOS=15
VF1 2 INN 0V
F1 3 0 VF1 1
E1 1 0 INP 0 1
Rn 2 1 {Rn}
Ct 0 3 CF1 1
Rt 0 3 {RT}
EABM1 OUT 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
.model CF1 CAP C={SQRT(RT^2-1)/(2*F1*RT*Pi)}
.ENDS OPAMP_T2_F1
*$
В завершение построим модели трансимпедансных ОУ - OPAMP_T3 (частотно независимая) и OPAMP_T3_F1 (частотно-зависимая). Они отличаются наличием резистора Rn (выходное сопротивление входного буфера) и резистора Rout (выходное сопротивление выходного буфера). Они также предназначены в основном для исследования влияния внешней обвязки и частотного полюса ОУ на характеристики усилительных и фильтрующих схем.
Схема для экстракции PSpice макромодели частотно не зависимой однополюсной макромодели OPAMP_T3 трансимпедансного ОУ показана на Рисунке 6. Результат экстракции представлен в Листинге 8. Готовая PSpice макромодель этого ОУ для OrCAD v16.6 представлена в Листинге 10.
Схема для экстракции PSpice макромодели частотно-зависимой однополюсной макромодели OPAMP_T3_F1 трансимпедансного ОУ показана на Рисунке 9. Результат экстракции представлен в Листинге 6. Готовая PSpice макромодель этого ОУ для OrCAD v16.6 представлена в Листинге 10.
 |
||
| Рисунок 8. | Поведенческая модель OPAMP_T3 частотно-зависимого трансимпедансного ОУ |
|
 |
||
| Рисунок 9. | Поведенческая модель OPAMP_T3_F1 частотно-зависимого трансимпедансного ОУ |
|
Листинг 8
* source ORCAD_166
E_E1 1 0 INP 0 1
E_ABM1 4 0 VALUE { LIMIT(V(3),VNEG,VPOS) }
R_Rout OUT 4 {Rout} TC=0,0
R_Rn 2 1 {Rn} TC=0,0
X_F1 2 INN 3 0 SCHEMATIC1_F1
R_Rt 0 3 {Rt} TC=0,0
.PARAM rt=10meg vneg=-15 rout=10 rn=25 vpos=15
.subckt SCHEMATIC1_F1 1 2 3 4
F_F1 3 4 VF_F1 1
VF_F1 1 2 0V
.ends SCHEMATIC1_F1
Листинг 9
* source ORCAD_166
E_E1 1 0 INP 0 1
C_Ct 0 3 {CF1} TC=0,0
E_ABM1 4 0 VALUE { LIMIT(V(3),VNEG,VPOS) }
R_Rout OUT 4 {Rout} TC=0,0
R_Rn 2 1 {Rn} TC=0,0
X_F1 2 INN 3 0 SCHEMATIC1_F1
R_Rt 0 3 {Rt} TC=0,0
.PARAM rt=10meg vneg=-15 cf1=1p rn=25 rout=10 vpos=15
.subckt SCHEMATIC1_F1 1 2 3 4
F_F1 3 4 VF_F1 1
VF_F1 1 2 0V
.ends SCHEMATIC1_F1
Листинг 10
*$
* Device name: OPAMP_T3
* Device type: Transimpedance OpAmp (DC model)
*
* Rt - DC Transimpedanc
* Rn - Input resistance
* Rout - Output resistance
*
.SUBCKT OPAMP_T3 INP INN OUT
+ PARAMS: RT=10MEG RN=25 ROUT=10 VNEG=-15 VPOS=15
VF1 2 INN 0V
F1 3 0 VF1 1
E1 1 0 INP 0 1
Rn 2 1 {RN}
Rt 0 3 {RT}
Rout OUT 4 {ROUT}
EABM1 4 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
.ENDS OPAMP_T3
*$
* Device name: OPAMP_T3_F1
* Device type: Transimpedance OpAmp (Frequency-dependent)
*
* Rt - DC Transimpedanc
* F1 - Freguence single Transimpedanc
* Rn - Input resistance
* Rout - Output resistance
*
.SUBCKT OPAMP_T3_F1 INP INN OUT
+ PARAMS: RT=10MEG F1=1E9 RN=25 ROUT=10 VNEG=-15 VPOS=15
VF1 2 INN 0V
F1 3 0 VF1 1
E1 1 0 INP 0 1
Rn 2 1 {RN}
Rt 0 3 {RT}
Ct 0 3 CF1 1
Rout OUT 4 {ROUT}
EABM1 4 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
.model CF1 CAP C={SQRT(RT^2-1)/(2*F1*RT*Pi)}
.ENDS OPAMP_T3_F1
*$
Для OrCAD v9.1 макромодели будут немного отличаться, так как число Pi потребуется указать явно, директивой .PARAM (Листинг 11).
Листинг 11. Библиотека для OrCAD v. 9.1
* PSpice Model Editor - Version 9.1
*
* Library of new analog primitives
* Date: 25 August 2016
*$
* Device name: OPAMP_T1
* Device type: Transimpedance OpAmp (DC model)
*
* Rt - DC Transimpedanc
*
.SUBCKT OPAMP_T1 INP INN OUT
+ PARAMS: RT=10MEG VPOS=15 VNEG=-15
VF1 1 INN 0V
F1 2 0 VF1 1
E1 1 0 INP 0 1
Rt 0 2 {RT}
EABM1 OUT 0 VALUE {LIMIT(V(2),VNEG,VPOS)}
.ENDS OPAMP_T1
*$
* Device name: OPAMP_T1_F1
* Device type: Transimpedance OpAmp (Fequency-dependent)
*
* Rt - DC Transimpedanc
* F1 - Freguence single Transimpedanc
*
.SUBCKT OPAMP_T1_F1 INP INN OUT
+ PARAMS: RT=10MEG F1=1E9 VPOS=15 VNEG=-15
.PARAM: Pi=3.1415926535897932385
VF1 1 INN 0V
F1 2 0 VF1 1
E1 1 0 INP 0 1
Ct 0 2 CF1 1
Rt 0 2 {RT}
EABM1 OUT 0 VALUE {LIMIT(V(2),VNEG,VPOS)}
.model CF1 CAP C={SQRT(RT^2-1)/(2*F1*RT*Pi)}
.ENDS OPAMP_T1_F1
*$
* Device name: OPAMP_T2
* Device type: Transimpedance OpAmp (DC model)
*
* Rt - DC Transimpedanc
* Rn - Input resistance
*
.SUBCKT OPAMP_T2 INP INN OUT
+ PARAMS: RT=10MEG RN=25 VNEG=-15 VPOS=15
VF1 2 INN 0V
F1 3 0 VF1 1
E1 1 0 INP 0 1
Rn 2 1 {Rn}
Rt 0 3 {RT}
EABM1 OUT 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
.ENDS OPAMP_T2
*$
* Device name: OPAMP_T2_F1
* Device type: Transimpedance OpAmp (Fequency-dependent)
*
* Rt - DC Transimpedanc
* F1 - Freguence single Transimpedanc
* Rn - Input resistance
*
.SUBCKT OPAMP_T2_F1 INP INN OUT
+ PARAMS: RT=10MEG F1=1E9 RN=25 VNEG=-15 VPOS=15
.PARAM: Pi=3.1415926535897932385
VF1 2 INN 0V
F1 3 0 VF1 1
E1 1 0 INP 0 1
Rn 2 1 {Rn}
Ct 0 3 CF1 1
Rt 0 3 {RT}
EABM1 OUT 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
.model CF1 CAP C={SQRT(RT^2-1)/(2*F1*RT*Pi)}
.ENDS OPAMP_T2_F1
*$
* Device name: OPAMP_T3
* Device type: Transimpedance OpAmp (DC model)
*
* Rt - DC Transimpedanc
* Rn - Input resistance
* Rout - Output resistance
*
.SUBCKT OPAMP_T3 INP INN OUT
+ PARAMS: RT=10MEG RN=25 ROUT=10 VNEG=-15 VPOS=15
VF1 2 INN 0V
F1 3 0 VF1 1
E1 1 0 INP 0 1
Rn 2 1 {RN}
Rt 0 3 {RT}
Rout OUT 4 {ROUT}
RL OUT 0 1T
EABM1 4 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
.ENDS OPAMP_T3
*$
* Device name: OPAMP_T3_F1
* Device type: Transimpedance OpAmp (Frequency-dependent)
*
* Rt - DC Transimpedanc
* F1 - Freguence single Transimpedanc
* Rn - Input resistance
* Rout - Output resistance
*
.SUBCKT OPAMP_T3_F1 INP INN OUT
+ PARAMS: RT=10MEG F1=1E9 RN=25 ROUT=10 VNEG=-15 VPOS=15
.PARAM: Pi=3.1415926535897932385
VF1 2 INN 0V
F1 3 0 VF1 1
E1 1 0 INP 0 1
Rn 2 1 {RN}
Rt 0 3 {RT}
Ct 0 3 CF1 1
Rout OUT 4 {ROUT}
RL OUT 0 1T
EABM1 4 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
.model CF1 CAP C={SQRT(RT^2-1)/(2*F1*RT*Pi)}
.ENDS OPAMP_T3_F1
*$
