Теперь, по аналогии, построим поведенческие частотно-зависимые однополюсные макромодели полностью дифференциальных ОУ. Как устроена макромодель этих ОУ для постоянного тока было описано в журнале РАДИОЛОЦМАН за июнь 2016 (61) [6]. Пользуясь этим материалом, нарисуем новые схемы макромоделей, с учётом предложенной в статье схемотехники частотно-зависимого усилительного каскада.
Схема для экстракции Pspice макромодели частотно-зависимой однополюсной макромодели полностью дифференциального ОУ без входом смещения VOCM показана на Рисунке 7. Результат экстракции представлен в Листинге 5. Готовая Pspice макромодель этого ОУ для OrCAD v16.6 представлена в Листинге 7. Макромодель получила имя OPAMP_FD1_F1.
Схема для экстракции Pspice макромодели частотно-зависимой однополюсной макромодели полностью дифференциального ОУ с входом смещения VOCM показана на Рисунке 8. Результат экстракции представлен в Листинге 6. Готовая Pspice макромодель этого ОУ для OrCAD v16.6 представлена в Листинге 8. Макромодель получила имя OPAMP_FD2_F1.
Для OrCAD v9.1 макромодели будут немного отличаться, так как число Pi потребуется указать явно, директивой .PARAM (см. приложения к статье).
 |
|
| Рисунок 7. | Поведенческая модель частотно-зависимогополностью дифференциального ОУ без входа смещения |
 |
|
| Рисунок 8. | Поведенческая модель частотно-зависимого полностью дифференциального ОУ с входом смещения VOCM. |
Листинг 5
* source ORCAD_166
C_C1 0 2 CF1 TC=0,0
R_GAIN1 0 2 GAIN TC=0,0
G_G1 2 0 INP 1 1
E_ABM1 OUTN 0 VALUE {LIMIT(V(2),VNEG,VPOS)}
E_ABM2 OUTP 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
G_G2 3 0 INN 1 1
R_GAIN2 0 3 GAIN TC=0,0
C_C2 0 3 CF1 TC=0,0
E_E3 1 0 VALUE { V(0,4)*GAIN }
E_E4 4 OUTP OUTN OUTP 0.5
Листинг 6
* source ORCAD_166
C_C1 0 2 CF1 TC=0,0
R_GAIN1 0 2 GAIN TC=0,0
G_G1 2 0 INP 1 1
E_ABM1 OUTN 0 VALUE {LIMIT(V(2),VNEG,VPOS)}
E_ABM2 OUTP 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
G_G2 3 0 INN 1 1
R_GAIN2 0 3 GAIN TC=0,0
C_C2 0 3 CF1 TC=0,0
E_E3 1 0 VALUE { V(VOCM,4)*GAIN }
E_E4 4 OUTP OUTN OUTP 0.5
Листинг 7
* PSpice Model Editor - Version 16.6
*$
* Device type: Frequency-dependent Fully Differential operational amplifier
* Device name: OPAMP_FD1_F1
* Aythor: Petrakov Oleg [email protected]
* Date: 25 August 2016
*
* F1 - Freguence single gain
* GAIN - Gain with the opened feedback coupling
*
.subckt OPAMP_FD1_F1 INP INN OUTP OUTN
+ PARAMS: GAIN=1e6 F1=1MEG VPOS=15 VNEG=-15
R_GAIN1 0 2 {GAIN}
R_GAIN2 0 3 {GAIN}
C1 0 2 CF1 1
C2 0 3 CF1 1
G1 2 0 1 INP 1
G2 3 0 INN 1 1
E1 0 OUTN VALUE {LIMIT(V(2),VNEG,VPOS)}
E2 OUTP 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
E3 1 0 VALUE {V(0,4)*GAIN}
E4 4 OUTP OUTN OUTP 0.5
.model CF1 CAP C={SQRT(GAIN^2-1)/2/F1/Pi/GAIN}
.ends
*$
Листинг 8
* PSpice Model Editor - Version 16.6
*$
* Device type: Frequency-dependent Fully Differential operational amplifier
* Device name: OPAMP_FD2_F1
* Aythor: Petrakov Oleg [email protected]
* Date: 25 August 2016
*
* F1 - Freguence single gain
* GAIN - Gain with the opened feedback coupling
*
.subckt OPAMP_FD2_F1 INP INN OUTP OUTN VOCM
+ PARAMS: GAIN=1e6 F1=1MEG VPOS=15 VNEG=-15
R_GAIN1 0 2 {GAIN}
R_GAIN2 0 3 {GAIN}
C1 0 2 CF1 1
C2 0 3 CF1 1
G1 2 0 1 INP 1
G2 3 0 INN 1 1
E1 0 OUTN VALUE {LIMIT(V(2),VNEG,VPOS)}
E2 OUTP 0 VALUE {LIMIT(V(3),VNEG,VPOS)}
E3 1 0 VALUE { V(VOCM,4)*GAIN }
E4 4 OUTP OUTN OUTP 0.5
.model CF1 CAP C={SQRT(GAIN^2-1)/2/F1/Pi/GAIN}
.ends
*$
Тестирование макромоделей ОУ
Проверим, что созданные модели ведут себя как операционные усилители. На Рисунке 9 изображена схема инвертирующего усилителя с коэффициентом усиления К = -R2/R1 = -2. Результат моделирования (Рисунок 10) подтверждает этот факт.
 |
|
| Рисунок 9. | Инвертирующего усилителя с коэффициентом усиления К=-2. |
 |
|
| Рисунок 10. | Результат моделирования усилителя (Рисунок 9). |
На Рисунке 11 показана основная схема включения полностью дифференциального ОУ [6]. В этой схеме мы будем тестировать модель OPAMP_FD2_F1 с входом смещения VOCM. К входу VOCM подключим источник опорного напряжения Vref = 3 В. Коэффициент схемы К= -R3/R1 = V(V1:+,V1:-)/ V(OUT-,OUT+) = -2. Результат моделирования (Рисунок 12) подтверждает правильность работы модели OPAMP_FD2_F1 для этого случая. Модель OPAMP_FD1_F1 читатели могут проверить самостоятельно, так как эти модели одинаковые по идеологии.
 |
|
| Рисунок 11. | Основная схема включения полностью дифференциального ОУ с использованием модели OPAMP_FD2_F1. |
 |
|
| Рисунок 12. | Результат моделирования основной схемы включения полностью дифференциального ОУ с использованием модели OPAMP_FD2_F1. |
На Рисунке 13 показана схема для измерения усиления и частоты единичного усиления стандартного ОУ с разомкнутой обратной связью. На схеме директивой PARAMETERS определены глобальные параметры: G – для усиления, F – для частоты. Парамеры GAIN и F1 модели ОУ выражены через эти глобальные параметры. Моделировать АЧХ (AC Sweep) будем в режиме Parametric Sweep (Вариация параметров) с вариацией глобальных параметров G и F.
Сначала проверим управляемость параметра GAIN и правильность моделирования параметра F1 = 1 МГц модели стандартного ОУ. Для этого установим вариацию глобального параметра G = 1E4, 1E5, 1E6. Результаты моделирования (Рисунок 14) показывают, что для этого теста параметры модели ОУ GAIN и F1 моделируются правильно. Так как на входе усилителей стоит источник напряжения с напряжением 1 В, то напряжение на выходе OUT будет численно равно усилению.
Теперь проверим управляемость параметра F1 и правильность моделирования параметра GAIN = 1Е6 модели стандартного ОУ. Для этого установим вариацию глобального параметра F = 1E4, 1E5, 1E6. Результаты моделирования (Рисунок 15) показывают, что для этого теста параметры модели ОУ GAIN и F1 моделируются правильно. Так как на входе усилителей стоит источник напряжения с напряжением 1 В, то напряжение на выходе OUT будет численно равно усилению.
 |
|
| Рисунок 13. | Схема для измерения усиления и частоты единичного усиления стандартного ОУ. |
 |
|
| Рисунок 14. | Результат моделирования параметра F1 при изменении параметра G=1E4, 1E5, 1E6. |
 |
|
| Рисунок 15. | Результат моделирования параметра GAIN при изменении параметра F=10 кГц, 100 кГц, 1 МГц. |
Такие же тесты были проведены для моделей полностью дифференциальных ОУ (см. приложения к статье) и показали аналогичные результаты.
Применение частотно-зависимых моделей ОУ на практике
Приведём практические примеры использования однополюсных частотно-зависимых моделей ОУ. На Рисунке 16 представлена схема активного узкополосного режекторного фильтра, построенного на базе двойного Т-моста. Теоретически фильтр имеет единичный коэффициент передачи во всём диапазоне частот, кроме частоты режекции 1 кГц. Практически нам достаточно фильтра с единичным усилением в диапазоне 0…20 кГц и частотой режекции 1 кГц. В режиме Parametric Sweep, для этого ОУ с GAIN=1E4, было промоделировано три случая АЧХ фильтра, когда F1 = 20 кГц, 100 кГц, 1 МГц. По результатам моделирование (Рисунок 17) видно, что для такого фильтра нужен ОУ с характеристиками не хуже, чем GAIN=1E4, F1=1MEG.
 |
|
| Рисунок 16. | Схема режекторного фильтра на 1 кГц. |
 |
|
| Рисунок 17. | Результат моделирования режекторного фильтра для ОУ с параметрами GAIN=1E4 и F1=20 кГц, 100 кГц, 1 МГц . |
На Рисунке 18 представлена схема полностью дифференциального полосового фильтра Баттерворта второго порядка [6] с центральной частотой 10 кГц и шириной полосы по уровню 3дБ 1 кГц. Его коэффициент усиления на центральной частоте 20 ДБ. В режиме Parametric Sweep, для GAIN=1E5, было промоделировано три случая АЧХ, когда F1 = 50 кГц, 300 кГц, 10 МГц. По результатам моделирование (Рисунок 19) видно, что для такого фильтра нужен ОУ с характеристиками не хуже, чем GAIN=1E5, F1=10MEG.
 |
|
| Рисунок 18. | Полосовой фильтр Баттерворта второго порядка с центральной частотой 10 кГц. |
 |
|
| Рисунок 19. | Результат моделирования АЧХ полосового фильтра Баттерворта с центральной частотой 10 кГц (Усиление в децибелах) |
Заключение
В принципе, читатели могут пойти дальше, добавив в текст макромоделей другие параметры не идеальности ОУ, например: входное сопротивление для дифференциального сигнала, входное сопротивление для синфазного сигнала, выходное сопротивление, напряжение смещения нуля. Эти справочные данные есть и для отечественных ОУ. Таким образом, можно получить более точные модели конкретных ОУ. Во многих случаях достаточно различать хотя бы ОУ с полевыми и биполярными транзисторами на входе.
Эти макромодели можно подключить к любой программе моделирования электрических схем, поддерживающей PSpice. Существуют также другие программы со Spice-подобными языками моделирования, однако эти макромодели потребует минимальных усилий для их адаптации.
Подключение библиотек к OrCAD
Для подключения библиотек к OrCAD v16.6 при его стандартной инсталляции необходимо выполнить следующие действия (Для OrCAD v9.1 действия примерно аналогичны):
- Разархивировать файл с приложениями к статье в любое место на диске компьютера.
- Скопировать папку PSPICE166_Articles с библиотеками в каталог c:Cadence.
- Скопировать текстовый файл nom_user_Articles.lib в папку C:CadenceSPB_16.6 oolspspicelibrary. В этом файле должен содержаться следующий текст, с указанием путей к библиотечным файлам.
* Library of user Oleg Petrakov devices: Analog and Digital *
* ---------- ARTIKLES_Potentiometer -------------------------------------------------
.lib c:CadencePSPICE166_ArticlesPotentiometerVC_POT.lib
.lib c:CadencePSPICE166_ArticlesPotentiometerVC_POTV.lib
.lib c:CadencePSPICE166_ArticlesPotentiometerOhmmeter.lib
.lib c:CadencePSPICE166_ArticlesPotentiometerKR1182PM1.lib
* ---------- ARTIKLES_Fully Differential operational amplifier --------------------
.lib c:CadencePSPICE166_ArticlesOperational_AmplifiersOPAMP_FD1.lib
.lib c:CadencePSPICE166_ArticlesOperational_AmplifiersOPAMP_FD2.lib
.lib c:CadencePSPICE166_ArticlesOperational_AmplifiersOPAMP_FD1_F1.lib
.lib c:CadencePSPICE166_ArticlesOperational_AmplifiersOPAMP_FD2_F1.lib
.lib c:CadencePSPICE166_ArticlesOperational_AmplifiersTHS4120.lib
* -------- ARTICLES Frequency-dependent standard operational amplifiers -------
.lib c:CadencePSPICE166_ArticlesOperational_AmplifiersOPAMP_F1.lib
* end of library file
- Отредактировать текстовый файл c:CadenceSPB_16.6 oolspspicelibrary om.lib. В конец файла следует записать следующие строки, чтобы подключить пользовательскую библиотеку nom_user_Articles.lib и сохранить изменённый файл.
* User Oleg Petrakov
.lib "nom_user_Articles.lib"
* end of library file
- Запустить проект OrCAD, содержащий новые библиотечные компоненты (см. приложения), и убедиться, что PSpice моделирование происходит. На этом всё!
Литература
- Важенин, В. Г. Аналоговые устройства на операционных усилителях: учебное пособие. Екатеринбург: Изд-во Урал. Ун-та, 2014 г.
- Картер Брюс. Операционные усилители для всех / Брюс Картер и Рон Манчини; пер. с англ. А. Н. Рабодзея. — М.: Додэка-ХХ1, 2011. — 544 с.: ил. — (Серия «Схемотехника»).
- Разевиг В. Д. Система проектирования OrCAD 9.2. СОЛОН. Москва 2001 г.
- Архангельский А. Я. PSpice и Design Center. Ч. 1. Схемотехническое моделирование. Модели элементов. Макромоделирование. М.: МИФИ, 1996 г.
- Петраков О. М. Создание аналоговых PSPICE-моделей радиоэлементов. М.: ИП РадиоСофт, 2004.— 208 с.: ил.— (Книжная полка радиолюбителя. Вып. 8)
- Журнал РАДИОЛОЦМАН, Июнь 2016 (61). Статья «Идеализированная Pspice модель полностью дифференциального операционного усилителя». Петраков О. М.
